globals
[ container-diameter
  container-radius
  container-area
  escape-radius
  new-size
  new-radius
  overlap-radius
  overlap-count
  countdown
  ; circle-count
  pause?
  time-since-zero
  master-rad-inc
  master-jiggle
  rad-inc ;; radius increment
  jiggle ;; movement caused by collisions
  jiggle-timeout-inc
  jiggle-timeout ;; max ticks for jiggling before reducing jiggle/rad-inc
  last-zero
  this-zero
  next-zero
  hex-pack-area
  hex-pack-radius
  hex-pack-density
  collision-buffer
  collision-radius
  last-good-size
  ordered-circles
  history
  hist-len
  circ-color
]

breed [ circles circle ]
circles-own
[  moved?
   ;; circles that overlap this circle
   d
   overlaps
   vx vy
   xx yy
   overcount
   last-good-position
]
undirected-link-breed [ collisions collision ]
collisions-own
[ age ]

;;=========================================================================================
;;=========================================================================================
;; the breed for the mouse pointer
;; defined last so pointer is on top of all other shapes
breed [ pointers pointer ]
pointers-own
[ dragged 
  hovered 
  hover-radius^2
  click-time
  outside?
  in-click?
  mx my
]
;;=========================================================================================
;;=========================================================================================


to setup
   
   ca
   
   ;; create the circle that defines the arena
   set container-diameter min (list world-width world-height) * .8
   set container-radius  container-diameter / 2
   set container-area pi * container-radius ^ 2 
      create-turtles 1
   [ home
     set shape "circle-edge"
     set size container-diameter
     set color white
     stamp
     die
   ]
   
   reset-history
   set-default-shape circles "circle-edge"
   set circle-count 3 * k * (k + 1) + 1
   set master-rad-inc .01
   set rad-inc master-rad-inc
   set master-jiggle 1.55
   set jiggle master-jiggle
   set jiggle-timeout-inc circle-count * 2
   set jiggle-timeout jiggle-timeout-inc
   set collision-buffer 1e-5

   set last-zero 0
   set next-zero 1000
   
   ;; now create the circles
  
   setup-circles
   set ordered-circles sort circles
end
   
to setup-circles
   let hex-pack-size container-radius * 2 / (k * 2 + 1)
   set circ-color blue
   foreach (n-values (k + 1) [ ? ])
   [ let r ?
     create-ordered-circles (max (list (r * 6) 1))
     [ set size hex-pack-size
       ; set label hex who
       set color circ-color
       jump r * hex-pack-size
     ]
   ] 
   while [ any? circles with [ any? collision-set size ]]
   [ set hex-pack-size hex-pack-size * .999
     ask circles [ set size hex-pack-size ]
   ]
   ask min-one-of circles [ who ] [ set shape "circle" ]
   ask max-one-of circles [ who ] [ set shape "circle" ]
   set new-size hex-pack-size
   save-arrangement
   update-size 0
end

to go
   mouse:go
   ifelse pause? != true
   [
   set overlap-count 0
   
   ;; detect collisions, accumulate total collision "push"
   set collision-radius new-size ; + collision-buffer * 2
   let collision-fade-delay 1
   let ticks+collision-fade-delay ticks + collision-fade-delay

   ask circles
   [ set xx 0
     set yy 0
     if any? other circles with [ nearly-same self myself ]
     [ rt random-float 360 jump new-size * .5 
     ]
      ifelse who = max [ who ] of circles
      [ set overlaps no-turtles
        set overcount 0
      ]
      [ 
     
     
     set overlaps collision-set new-size
     
     
     set overcount 0
     ;; find collisions with other circles

     ifelse any? overlaps
     [
       set overcount count overlaps
       set xx xx + bounce * sum [ (xcor + (collision-radius) * sin (safe-towards myself) - [ xcor ] of myself)  ] of overlaps 
       set yy yy + bounce * sum [ (ycor + (collision-radius) * cos (safe-towards myself) - [ ycor ] of myself)  ] of overlaps 
       set color circ-color - 2
     ]
     [ set color circ-color
     ]
    ]
;  ]
   
   ;; collisions affect circles
 ; ask circles
  ;[  ;calculate new x, y coords after "push"
     let new-x xcor + xx
     let new-y ycor + yy
     
     ;; prevent escape from edge
     if sqrt (new-x * new-x + new-y * new-y) > escape-radius
     [ let head atan new-x new-y
       set new-x ( escape-radius - collision-buffer ) * sin head
       set new-y ( escape-radius - collision-buffer ) * cos head
       set xx new-x - xcor
       set yy new-y - ycor
     ]
     if who > 1 [ setxy new-x new-y  ]
     let move-dist sqrt (xx * xx + yy * yy)
     ifelse move-dist > 0
     [ set overlap-count overlap-count + 1
       set moved? true
     ]
     [ set moved? false
     ] 
     ;; create collision vis.
     if show-collisions?
     [ if show-collisions?
       [ create-collisions-with overlaps
         [ set thickness 0
           set color white
           set thickness .25
           ;set color scale-color red severe 0 .001
         ]
         ;; refresh age of all current collisions
         ask (link-set [collision-with myself ] of overlaps)
         [ set age ticks+collision-fade-delay
         ] 
       ]
     ]
   ]
;; kill any old collisions
   ifelse show-collisions?
   [
     ask collisions with [ age != ticks+collision-fade-delay ]
     [ ifelse age < ticks
       [ die ]
       [ ; set color scale-color gray  (age - ticks) 0 collision-fade-delay
       ]
     ]  
   ]
   
   [ if any? collisions
     [ ask collisions [ die ]
     ]
   ]
   set history lput overlap-count but-first history
   set-current-plot-pen "default"
   plot overlap-count
   set-current-plot-pen "mean"
   plot mean history
   
   ifelse overlap-count = 0
   [ 
       save-arrangement
       update-size rad-inc
       if clear-plot-at-zero? [  clear-plot ]
   ]
   [ set time-since-zero time-since-zero + 1
     ;if time-since-zero > jiggle-timeout-inc 
     ;[ set jiggle-timeout-inc jiggle-timeout-inc * 1.01
     ;  set jiggle jiggle * .75
     ;  let old-inc rad-inc
     ;  set rad-inc rad-inc * .75
     ;  update-size (- old-inc)
     ;  set time-since-zero 0
     ;  if rad-inc < .001
     ;  [ ask collisions [ die ]
     ;    ask circles [ set label "" ]
     ;    ask pointers [ die ]
     ;    display
     ;    stop stop
     ;  ]
     ;]

     
   ]
   tick
   ]
   [ display
   ]
   set pause? false
   if ticks > next-zero
   [ restore-arrangement
     ask circles [ set label "" ]
     ask pointers [ die ]
     update-size 0
     ;; SHOW HEX PACK RADIUS
     create-turtles 1
     [ home
       set shape "circle-edge"
       set size hex-pack-radius * 2
       set color YELLOW
       stamp
       die
     ]
     display
     stop stop
   ]
end

to-report collision-set [ coll-rad ]
   report other circles in-radius coll-rad
end    

to reset-history
   set hist-len 100
   set history n-values hist-len [ circle-count ]
end

to-report safe-towards [ agent ]
   ifelse [ xcor] of agent = xcor or [ ycor ] of agent = ycor
   [ report 0 ]
   [ report (1 - random-float 2 + towards agent )]
end
   
to save-arrangement
   ask circles
   [ set last-good-position (list xcor ycor)
   ]
   set last-good-size new-size
end

to restore-arrangement
   set new-size last-good-size
   ask circles
   [ setxy (first last-good-position)(last last-good-position)
     set size new-size
   ]
   ask collisions [ die ]
end
   

to update-size [ #new-size ]
   set new-size new-size + #new-size
   ask circles
   [ ;; inflate the turtle
     set size new-size
     set moved? false
   ]

   set this-zero ticks
   set next-zero (max (list 2000 (this-zero + 10 * (this-zero - last-zero)))) 
   set last-zero this-zero
   reset-history
   set new-radius new-size * .5
   set escape-radius container-radius - new-radius
   ; set overlap-radius new-size 
   
   set circ-color wrap-color circ-color + 10
   
   let circle-area circle-count * pi * (new-size * .5) ^ 2
   let density circle-area / container-area
   let d/d circle-count / density
   

   set hex-pack-radius (k * 2 + 1) * new-size * .5
   set hex-pack-area pi * hex-pack-radius * hex-pack-radius 
   set hex-pack-density circle-area / hex-pack-area
   ask patch ( max-pxcor ) ( max-pycor - 1 ) [ set plabel ( word "r: " precision new-size 5 "  " ) ]
   ask patch ( max-pxcor ) ( max-pycor - 3 ) [ set plabel ( word "n0: " precision next-zero 0 "  " ) ]
   
   ask patch ( max-pxcor ) ( min-pxcor + 5 ) [ set plabel ( word "d: " precision density 5 ) ]
   ask patch ( max-pxcor ) ( min-pxcor + 3 ) [ set plabel ( word "hd: " precision hex-pack-density 5 ) ]
   ask patch ( max-pxcor ) ( min-pxcor + 1 ) [ set plabel ( word "D/d: " precision d/d 5 ) ]
   set time-since-zero 0
end


;;=========================================================================================
;;=========================================================================================
;;=========================================================================================
;;=========================================================================================
;; MOUSE DRIVER
;;=========================================================================================
;;=========================================================================================
;;=========================================================================================
;;=========================================================================================

to mouse:go
   if not any? pointers [ mouse:setup-pointer ]
   ask pointers
   [ ifelse mouse-inside?
     [ ;; mouse is inside
       set mx mouse-xcor
       set my mouse-ycor
       setxy mx my
       ;; did it just come inside?
       if outside?
       [ set outside? false
         mouse:do-go-inside
       ]
       ifelse mouse-down?
       [ if not in-click? [ set in-click? true mouse:do-click-start ]  mouse:do-down ]
       
       [ ;; mouse is up
         
         ;; did it just come up?
         if in-click?
         [ set in-click? false
           mouse:do-click-end
         ]
         mouse:do-hover
       ]
     ]
     [ ;; mouse is outside
       ;; did it just come outside
       if not outside?
       [ set outside? true
         mouse:do-go-outside
       ]
       mouse:do-outside 
     ]
   ]
end     

to mouse:do-go-inside debug-print "go-inside"
   show-turtle
end

to-report nearly-same [ a b ]
   report ( abs( [ xcor ] of a - [xcor] of b ) < collision-buffer and
   abs( [ ycor ] of a - [ycor] of b ) < collision-buffer
   )
end   
to mouse:do-click-start debug-print "click-start"
   
   if is-circle? hovered [ mouse:hover-drop ]
   if not is-circle? dragged 
   [ if any? circles
     [ set dragged min-one-of circles with [ mouse:quick-distance myself < [hover-radius^2] of myself ] [ mouse:quick-distance myself ]
     ]
   ]
end

to mouse:do-down
   if is-circle? dragged
   [ ask dragged [ setxy [ mx ] of myself [ my ] of myself ]
   ]
end

to mouse:do-click-end debug-print "click-end"
       set dragged nobody
end

to mouse:do-go-outside debug-print "go-outside"
   set dragged nobody
   if is-circle? hovered [ mouse:hover-drop ]
   hide-turtle
end

to mouse:do-outside
end

to mouse:do-hover 
   ifelse is-turtle? hovered 
   [ ifelse mouse:quick-distance hovered > hover-radius^2
     [ mouse:hover-drop
     ]
     [
     ]
   ]
   [  mouse:hover-pickup ]
end

to mouse:hover-pickup
   debug-print "get-hovered"
   let hoverable circles with [ mouse:quick-distance myself < size * size * .5 * .5 ] 
   if any? hoverable
   [ set hovered max-one-of hoverable [ who ]
     ask hovered [ begin-hover ]
     set hover-radius^2  .5 * .5 * size * size
     debug-print (word "(" hovered ")" )
   ]
end

to mouse:hover-drop
       debug-print "drop-hovered"
       ask hovered [ reset-hover ]
       set hovered nobody
end

to begin-hover
   set shape "circle"
end
   

to reset-hover
   set shape "circle-edge"
end   
to-report mouse:quick-distance [ agent ]
   ;; reports the square of the distance
   ;; avoids the slow square root function
   ;; useful when simply looking for nearest
   ;; or comparing distance
   ;; or comparing to a known squared distance
   let x2x [ xcor ] of agent - xcor
   let y2y [ ycor ] of agent - ycor
   report (x2x * x2x + y2y * y2y)
end

to mouse:setup-pointer
   create-pointers 1
   [ set shape "pointer"
     set color white
     set size 7
     set heading 0
     set dragged nobody
     set in-click? false
     set outside? true
     set hovered nobody
     hide-turtle
   ]
end
          
to debug-print [ message ]
   ;output-print message
end   

to-report hex [ number ]
   let hdigits "0123456789ABCDEF"
   let hx ""
   while [ number > 0 ]
   [ let ddigit number mod 16
     let hdigit item ddigit hdigits
     set hx (word hdigit hx)
     set number floor (number / 16)
   ]
   report hx
end
@#$#@#$#@
GRAPHICS-WINDOW
210
10
561
382
15
15
11.0
1
11
1
1
1
0
0
0
1
-15
15
-15
15
1
1
1
ticks

CC-WINDOW
5
529
972
624
Command Center
0

SLIDER
10
10
182
43
k
k
1
10
4
1
1
NIL
HORIZONTAL

BUTTON
10
50
180
83
setup / reset
setup
NIL
1
T
OBSERVER
NIL
S
NIL
NIL

BUTTON
10
90
70
123
NIL
go
T
1
T
OBSERVER
NIL
G
NIL
NIL

BUTTON
65
140
125
173
pop
ask max-one-of circles [ who ]\n[ die ]\nset circle-count count circles
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
25
200
180
233
show-collisions?
show-collisions?
0
1
-1000

PLOT
60
395
963
515
collisions
ticks
collisions
0.0
50.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -16777216 true
"mean" 1.0 0 -2674135 true

BUTTON
120
90
180
123
pause
set pause? true
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
25
240
180
273
clear-plot-at-zero?
clear-plot-at-zero?
1
1
-1000

SLIDER
572
56
744
89
bounce
bounce
1
1.75
1.05
.05
1
NIL
HORIZONTAL

INPUTBOX
574
94
729
154
circle-count
61
1
0
Number

BUTTON
45
305
155
338
clear-collisions
ask collisions [ die ]\nask circles [ set color blue ]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This model attempts to create dense-packings of equal-sized circles in a circle.

HOW IT WORKS
------------
The desired number of circles are created at random locations, inside the containing circle, at a small size, with no overlaps.

The circles are increased in size by a small amount.
If no circles overlap, the size is increased again.
If any circles overlap, some simple physical dynamics are applied.

The program is designed to use hexagon-pack numbers--becuase it is easy to compare the density of a hexagon arangement of circles in a circle to the tweaked desnse-packed arrangement.

HEGXAGONAL NUMBERS
------------------
||  K  |  R  | 3 * K * (K + 1) + 1 |
||  0  |  1  |   1 |
||  1  |  6  |   7 |
||  2  |  12 |  19 |
||  3  |  18 |  37 |
||  4  |  24 |  61 |
||  5  |  30 |  91 |

HOW TO USE IT
-------------
This section could explain how to use the model, including a description of each of the items in the interface tab.


THINGS TO NOTICE
----------------
This section could give some ideas of things for the user to notice while running the model.


THINGS TO TRY
-------------
This section could give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.


EXTENDING THE MODEL
-------------------
This section could give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.


NETLOGO FEATURES
----------------
This section could point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.


RELATED MODELS
--------------
This section could give the names of models in the NetLogo Models Library or elsewhere which are of related interest.

HEXAGONAL NUMBERS
-----------------
|   k      1           2           3           4            5 
| 
| per ring 1  (1 + 6 * 1) (1 + 6 * 2) (1 + 6 * 3) (1 + 6 * 4)  (1 + 6 * 5)
|
| total    1  (2 + 6 * 1) (3 + 6 * 3) (4 + 6 * 6) (5 + 6 * 10) (6 + 6 * 15)  


CREDITS AND REFERENCES
----------------------

Lubachevsky, D.B.; Graham, R.L. : "Dense Packings of 3k(k+1)+1 Equal Disks in a circle for k = 1, 2, 3, 4, and 5", February 24, 1995, AT&T Bell Laboratories.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

circle-edge
false
0
Circle -7500403 false true 0 0 300

circle-edge-dot
true
0
Circle -7500403 false true 0 0 300
Circle -1 true false 120 270 60

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

pointer
false
0
Polygon -7500403 true true 150 150 270 195 240 225 285 270 270 285 225 240 195 270

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.5
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@