globals
[ 
]


patches-own
[ v ;; elevation
  _v ;; floor of elevation * scalar
]

to startup setup end

to setup
   ca
   display-message
   [ "Welcome to the Terrain Generator Workshop"
     ""
     "Featuring an assortment of simulated terrain generators"
     ""
     "Press the generator button to generate a sample"
   ]
end



to go
   setup-terrain-midpoint-displacement-fractal smoothness  
end
   
to setup-terrain
   cp ct
end

to setup-terrain-midpoint-displacement-fractal [ #roughness ]
   ;; note that, unlike other implementations found on the web
   ;; this implementation does NOT require the field to be square, nor
   ;; does it require the field grid to be sized at (1 + 2^n)
   ;; i.e. it world for any size gird of any ratio.
   ;; this is because it dynamically finds the minimum power of two needed
   ;; to correctly populate the provided grid.
     
   let time0 timer
  
   setup-terrain
   
   let r #roughness
   let md 1
   let rr 2 ^ (- r)
   ;; which dimention is smaller?
   let dim min (list world-width world-height)
   ;; use that dimension to figure out the initial gap to use
   let g 2 ^ ( floor (log (dim ) 2) - 1 )
   let diamond-set 0
   let square-set 0
   
   ask patches [ set v 0 ]
   
   set diamond-set (patch-set patch 0 0)
   
   repeat floor log world-width 2
   [ 
    set square-set (patch-set [my-parent-corners g] of diamond-set)

    ask square-set
    [ set v v + plus-or-minus md + mean [ v ] of my-parent-corners g
    ]
 
    set diamond-set (patch-set [ my-parent-points g ] of square-set)
   
    ask diamond-set
    [ set v v + plus-or-minus md  + mean [ v ] of my-parent-points g
    ]

    set g g / 2
    set md md * rr
  ]
     
  let time1 timer
  let timespan floor (time1 - time0)
  if timespan < 1 [ set timespan "< 1" ]
  print (word "MDF terrain generated for " count patches " patches in " timespan " seconds.")
  
  compress
  color-default  
end

to setup-terrain-bespoke-atoll [  ]
   setup-terrain
   
   let deepest 0
   let peaks 0
  
   ; build an irregular, circular island
   ; with a shallow center lagoon
   
   cp
      
   ; create overall ring shape
   ask patches
   [ let temp distancexy 0 0 
     ; sin wave, 0 at center, peak in middle, 0 at corners
     let temp3 temp * 360 / 3 / 100
     ; scale as distance from edge
     let temp2  2 * sin ( temp * 180 / max-pxcor ) * ( max-pxcor - abs pxcor) / max-pxcor * ( max-pycor - abs pycor) / max-pycor
     set v world-width * sin temp3 * temp2
   ]
 
   
   ;  add random peaks and dips, repeat
   repeat max-pxcor
   [ ; "picking peak/pit location"
     ask patch 0 0 [ set v (- world-width) ]
     set peaks n-of max-pxcor patches
     ; "talking to peaks"
     ask peaks
     [ set v v + max-pxcor * random 2 * 2 - 1
     ]
   ]
   ;; 
   ; erode, just a bit
   repeat 4
   [ ask patch 0 0 [ set v min-pxcor ]
     diffuse v .8
   ]
   
   

   ; add "stress ridges"
  ask patches
  [ ; get distance from center
    let temp distancexy 0 0
    let temp2 0
    ; get angle from center
    ifelse temp = 0
    [ set temp 1
      set temp2 0
    ]
    [ set temp2 ( towardsxy 0 0 + 180 ) 
      if temp2 > 360
      [ set temp2 temp2 - 360 ]
    ]
    ; set number of ridges
    let temp3 temp2 * 50
    set v v + (max-pxcor * sin temp3 + sin temp * .2 )/ temp
  ]   
  
  ;; apply non-linear scaling of v
  ask patches
  [ set v v * v ]
  
  compress
  color-default 
end


to-report my-parent-corners [ g ]
   let -g (- g)
   report patches at-points (list (list -g g) (list g g) (list g -g) (list -g -g ) )
   ;; to-do: maybe pre-calculate the at-points lists for each generation
   ;; save some time over generating them over and over
end

to-report my-parent-points [ g ]
   let -g (- g)
   report patches at-points (list (list 0 -g ) (list g 0) (list 0 g) (list -g 0) )
end   

to-report plus-or-minus [ n ]
   report n - 2 * random-float n
end

to setup-terrain-circles [ #number #connect ]
   setup-terrain
   
   let mr world-width * #connect
   let mrd mr / #number * .9
   let r 0
   let h 0
   let a 0
   let pm 1
   
   let candidates [ patches in-radius (world-width * (.75 - #connect)) ] of patch 0 0
   ask n-of #number candidates
   [ set r (.1 + random-float .5) * mr
     set h (.1 + random-float 1) * mr
     if subtract? [ set pm (((random 2)* 2)- 1) ]
     set a 180 / r ;
     ask patches in-radius r
     [ set v v + pm * h * cos ( .5 * a * distance myself ) ]
     set mr mr - mrd
   ]
   compress
   
   color-default
end


to setup-terrain-line-dropper [ #number #roundness ]
   setup-terrain
   ;; this has got to be super naive.
   ;; that is, there has to be a better way to decide on what side
   ;; of a line a point lies.
   
   ;; pick a center point and an angle
   ;; if the difference tween the angle and the heading from this point
   ;; to the center point is > 0 (and less than 180, natch)
   ;; then increment this patch
   ;; i.e. elevate patches on only one side of the line
   
   repeat #number
   [ let center one-of patches
     let angle random 360
     let inc .5 *  random-float 1
     let curve .5 * world-width * .1 * .5 * (#roundness + random-float #roundness)
     ask center [ set v v - inc ]
     ask patches with [ self != center ]
     [ ;; depending on which side of the line this patch falls...
       ifelse subtract-headings angle towards center > 0 
       [ let dist-from-line (distance center * sin (180 -  (angle - towards center ) ) )
         let inc' inc
         ;; calculate a smooth transition from one plane to the other
         if dist-from-line <= curve
         [ set inc' inc' * cos (( (curve - dist-from-line) / curve ) * 180  ) ]  
         set v v + inc'
       ]
       [ set v v - inc
       ]
     ]
  ]
   compress
   color-default
end

to setup-terrain-sin-wave-overlay [ #number  #max-frequency ]
   setup-terrain
   repeat #number ;; apply this number of waves to the view
   [ let freq random-float #max-frequency
     let amp random-float 1
     let offset random-float 1 * freq
     let angle random-float 360
     let wx sin angle
     let wy (- cos angle)
     ask patches [ set v v + amp * (sin (offset + freq * (pxcor * wx + pycor * wy))) ]
     ;; uncomment the below lines to see the application of each layer
     ; color-sample 
     ; display
     ; wait .1     
   ]
   compress
   color-default
 end

to setup-terrain-particle-deposition [ #iterations  ]
   setup-terrain
   
   let sp patch 0 0
   repeat #islands
   [
   
   let md 1 ; #max-displacement
   let od md
   ; let r #roughness
   let md-d 1 / #iterations
   
   let p sp
   let op p
   
   repeat #iterations
   [ ask p
     [ set p one-of neighbors4
       ; set v v + random-float md
     ]
     while [ is-patch? p ]
     [ ask p
       [ set op p
         ; set v v + random-float md
         set p one-of neighbors4 with [ v < [ v ] of myself and atan 1 (v - [v] of myself) > 45 ]
       ]
     ]
     ask op [ set v v + random-float md ]
     set p op ; op
     set md md - md-d
   ]
     set sp one-of patches 
     
   ]
   
    
   compress
   color-default  
end


   
   

;;_,-'-._,-'-._,-'-._,-'-._,-'-._,-'-._,-'-.
;; COMMONI PROCEDURES
;;_,-'-._,-'-._,-'-._,-'-._,-'-._,-'-._,-'-.

to color-default 
   ifelse default = 4 [ color-monochrome map-color ][
   ifelse default = 3 [ color-false-color-contour map-color ][
   ifelse default = 2 [ color-cartegraphic-contour ][
   ifelse default = 1 [ color-contours divisions ][
                        color-contours-mono divisions map-color
   ]]]]
end   

to compress
   let new-max 9.9
   let minv min [ v] of patches
   let maxv max [ v ] of patches
   let spanv maxv - minv
   if-else spanv != 0 
   [ 
     let s new-max / spanv
   
     ask patches [ set v (v - minv) * s ]
   ]
   [ ask patches [ set v 0 ]
   ]
end     

to color-mono-simple [ #color ]
   ask patches [ set pcolor v - 5 + #color ]
end   

to color-monochrome [ #color ]
   ;; assumes v has been scaled to 0.0...9.9
   ;; color the patches using V as the brightness, using the given color
   ask patches
   [ let pc v - gray + #color
     if-else shaded? 
     [ set pc scale-color #color (2.5 + .5 * v) 0 9.9 
       let s patch-at 1 -1 
       if is-patch? s
       [ if-else [ v] of s < v
         [ set pc max (list (pc - 2) (pc - (pc mod 10))) ]
         [ set pc min (list (pc + 2) (9.9 + pc - (pc mod 10))) ]
       ]
     ]
     [ ]
     set pcolor pc
   ]
end

to color-contours [ #div ]
   ask patches [ set _v  floor( #div * v) ]
   
   ask patches
   [ let n count neighbors with [ _v = [ _v ] of myself ]
     if n < 1 [ set n 1 ]
     set pcolor scale-color _v  n 0 8 ]
end   

to color-contours-mono [ #div #color ]
   ask patches [ set _v floor ( #div * v ) ]
   ask patches
   [ let n 1.2 * count neighbors with [ _v = [ _v ] of myself ]
     if n < 1 [ set n 1 ]
     set pcolor scale-color #color n  0 8
   ]
end 

to color-false-color-contour [ #div ]
   ;; color the patches as a false-color contour map
   ;; color slider determines the number of colors in the map
      
   ifelse graduated?
   [ let $div 10 * (#div - 1 ) / 9.9
     ask patches [ set pcolor 5 +  int(v * $div) ] ]
   [ ask patches [ set pcolor 5 + 10 * int(v * #div) ] ]
   
   display
end


to color-no-scale [ #color ]
   ;; color the patches using V as the brightness, using the given color
   ;; does not assume v has been scaled
   
   let minv min [ v] of patches
   let maxv max [ v ] of patches
   let spanv maxv - minv
   
   let cs spanv * .1
   let mins minv - cs
   let maxs maxv + cs
   
   ;; default: V = brightness
   ask patches [ set pcolor scale-color #color v minv maxv ] 
end

to color-cartegraphic-contour
   ;; color the patches using typical terrain map colors
      
   ;; default: V = brightness
   ask patches
   [ ifelse v < 3 [ set pcolor scale-color blue  v  0 4 ][
     ifelse v < 4 [ set pcolor scale-color yellow (- v) -4.5 -2.5 ][
     ifelse v < 6 [ set pcolor scale-color lime  v 0  12 ][
     ifelse v < 8 [ set pcolor scale-color green  v 4  12 ][
     ifelse v < 9 [ set pcolor scale-color brown  v 6 12 ][
                     set pcolor scale-color gray   v 5 9.9
     ]]]]]
   ]
end

to setup-3d-vis
   if is-applet?
   [ user-message "Note, this feature does not work in applet mode.\n\nPlease run the model directly, to use the 3d Viewer."
     stop
   ]
   
   let alt world-width * .1
   
   if count turtles != count patches
   [ ct
     foreach reverse sort patches
     [ ask ? [ sprout 1
       [ set shape "line"
         __set-line-thickness 2
         set heading 0
     ] ] ]
   ]
   ask turtles
   [ set size v * alt
     set color pcolor
   ]
end

to clear-3d-vis
   ask turtles [ die ]
   user-message "If it is open, please close the 3d vis window."
end





;;_,-'-._,-'-._,-'-._,-'-._,-'-._,-'-._,-'-.
;; UTILITY PROCEDURES
;;_,-'-._,-'-._,-'-._,-'-._,-'-._,-'-._,-'-.

to display-message [ message-list ]
   let pr (max-pycor - 4 ) 
   foreach message-list
   [ ask patch max-pxcor pr
     [ set plabel ?
       set plabel-color white
     ]
     set pr pr - 3
   ]
end
@#$#@#$#@
GRAPHICS-WINDOW
410
10
677
298
128
128
1.0
1
15
1
1
1
0
0
0
1
-128
128
-128
128
1
1
1
ticks

CC-WINDOW
5
597
686
692
Command Center
0

BUTTON
10
10
105
43
fractal
setup-terrain-midpoint-displacement-fractal\nsmoothness  
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
45
390
180
423
monochrome
color-monochrome map-color 
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
110
10
205
43
smoothness
smoothness
0
1
0.79
.01
1
NIL
HORIZONTAL

SLIDER
185
390
277
423
map-color
map-color
5
135
75
10
1
NIL
HORIZONTAL

SLIDER
110
150
205
183
iterations
iterations
100
4000
4000
100
1
NIL
HORIZONTAL

BUTTON
10
150
105
183
dust drop
setup-terrain-particle-deposition\niterations
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
10
245
132
278
diffuse elevation
diffuse v .8 compress color-default  
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
10
305
100
338
NIL
setup-3d-vis\n
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
45
470
180
503
cartegraphic contour
color-cartegraphic-contour
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
105
305
195
338
NIL
clear-3d-vis
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

TEXTBOX
10
370
100
388
Map Coloring
11
0.0
1

SLIDER
10
400
43
570
default
default
0
4
2
1
1
NIL
VERTICAL

BUTTON
10
185
105
218
atoll
setup-terrain-bespoke-atoll
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
200
305
325
338
increase-3d-height
ask turtles [ set v v * 1.1 set size v * 10 ]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
210
80
305
113
max-frequency'
max-frequency'
1
20
10
1
1
NIL
HORIZONTAL

SLIDER
110
80
205
113
iterations'
iterations'
1
100
30
1
1
NIL
HORIZONTAL

BUTTON
10
80
105
113
sine drop
setup-terrain-sin-wave-overlay\niterations' max-frequency'
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
210
150
305
183
#islands
#islands
1
10
10
1
1
NIL
HORIZONTAL

BUTTON
45
430
180
463
false-color contour
color-false-color-contour map-color
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
280
430
395
463
graduated?
graduated?
1
1
-1000

SLIDER
185
430
277
463
stripes
stripes
2
13
5
1
1
NIL
HORIZONTAL

BUTTON
45
510
180
543
color contour lines
color-contours divisions
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
185
530
277
563
divisions
divisions
3
15
15
1
1
NIL
HORIZONTAL

BUTTON
45
550
180
583
contour lines
color-contours-mono divisions map-color
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
280
390
395
423
shaded?
shaded?
1
1
-1000

BUTTON
10
45
105
78
circle drop
setup-terrain-circles iterations'' connection
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
10
115
105
148
line drop
setup-terrain-line-dropper iterations'''  transition-width
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SLIDER
110
45
205
78
iterations''
iterations''
1
200
200
1
1
NIL
HORIZONTAL

SLIDER
110
115
205
148
iterations'''
iterations'''
1
100
15
1
1
NIL
HORIZONTAL

SLIDER
210
115
305
148
transition-width
transition-width
1
100
10
1
1
%
HORIZONTAL

SLIDER
210
45
305
78
connection
connection
.25
.5
0.37
.01
1
NIL
HORIZONTAL

BUTTON
140
245
242
278
flatten-water
ask patches with [ v < water-level ] [ set v water-level - .1 ]\ncolor-default
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
310
45
405
78
subtract?
subtract?
0
1
-1000

SLIDER
245
245
355
278
water-level
water-level
0
9.9
7.2
.1
1
NIL
HORIZONTAL

BUTTON
430
415
492
448
simple
color-mono-simple map-color
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
330
305
437
338
is-applet?
is-applet?
0
1
-1000

TEXTBOX
10
285
365
303
3D visualization (a hack of the 3D viewer, does not work in applet mode)
11
0.0
1

TEXTBOX
10
225
160
243
Manipulate the elevation
11
0.0
1

@#$#@#$#@
WHAT IS IT?
-----------
This model produces simulated terrain using a variety of algorithms

HOW IT WORKS
------------


HOW TO USE IT
-------------
Set the required parameters, click the buttons.

THINGS TO NOTICE
----------------

Midpoint Displacement: 

Notice how fast it is. This is because the implementation avoids use of ASK PATCHES and MOD, and instead directly creates agentsets of patches from the previous iterations patches.

THINGS TO TRY
-------------


EXTENDING THE MODEL
-------------------


NETLOGO FEATURES
----------------
at-points
patch-set

RELATED MODELS
--------------
watershed-model ;; also has a terrain generator, though it's rather primitive, special purpose, and silly.

CREDITS AND REFERENCES
----------------------
http://www.lighthouse3d.com/opengl/terrain/index.php3?mpd
http://www.lighthouse3d.com/opengl/terrain/index.php?mpd2
http://en.wikipedia.org/wiki/Diamond-square_algorithm
http://www.gameprogrammer.com/fractal.html#diamond
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
false
0
Line -7500403 true 150 0 150 300

line half
false
0
Line -7500403 true 150 0 150 150

line-r
true
0
Line -7500403 true 150 0 150 300

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@